Title Forum
IndexIndex  CalendarCalendar  GalleryGallery  Trợ giúpTrợ giúp  Tìm kiếmTìm kiếm  Đăng kýĐăng ký  Đăng NhậpĐăng Nhập  
News & Announcements
  • Gallery & Others
  • Top posters
 N.H.M (706)
 nhuantrung0210 (323)
 TjaGoChangLj (227)
 GVRFnu-Bjn (190)
 lisaidong (122)
 phongngan1997 (94)
 puppy:x* (85)
 anhcudo01 (69)
 taoghetmay (68)
 anhlathe47 (45)
Similar topics

Share | 
 

 Chương Tám - Tự tạo Object (Học visual basic 6.0)

Xem chủ đề cũ hơn Xem chủ đề mới hơn Go down 
Tác giảThông điệp
TjaGoChangLj
Administrator
Administrator


Thanked : 14


Bài gửiTiêu đề: Chương Tám - Tự tạo Object (Học visual basic 6.0)   16/6/2011, 1:48 pm

Khóa Hàm Thụ Visual Basic 6.0


Chương Tám - Tự tạo Object



<blockquote>

Từ trước đến giờ, ta lập trình VB6 bằng cách thiết kế các Forms rồi viết codes để xử lý các Events của
những controls trên Form khi Users click một Button hay Listbox, .v.v..
Nói chung, cách ấy cũng hữu hiệu để triển khai, nhưng nếu ta có thể hưởng được các lợi ích sau đây thì càng tốt hơn nữa:

  1. Dùng lại được code đã viết trước đây trong một dự án khác
  2. Dễ nhận diện được một lỗi (error) phát xuất từ đâu
  3. Dễ triển khai một dự án lớn bằng cách phân phối ra thành nhiều dự án nhỏ
  4. Dễ bảo trì

Mỗi lần dùng lại code, nếu để y nguyên xi con là lý tưởng. Việc ấy được gọi là Reusability. Nói cho đúng ra, dùng lại được
thật sự là khi ta chỉ cần dùng object code, đó là code đã được compiled rồi, tức là hoàn toàn không đụng đến source code.
Vì hể cho phép User sửa source code là tạo cơ hội cho bugs xuất hiện, rồi lại phải debug một lần nữa.
Sự thách đố chính của việc triển khai một dự án phần mềm lớn là thực
hiện đúng thời hạn (on time), không lố tài khóa (within budget) và dễ
bảo trì (ease of maintenance). Muốn đạt
được các mục tiêu ấy, ta phải triển khai nhanh và làm sao cho chương
trình ít có bugs, dễ bảo trì.


Giả dụ bạn đứng ra tổ chức một đám cưới. Thử tưởng tượng biết bao nhiêu
chuyện phải làm: từ danh sách quan khách, thiệp mời, ẩm thực,
xe cộ, chụp hình, quay phim, văn nghệ cho đến thủ tục nghi lễ, tiếp tân,
hoạt náo viên ..v.v.. Nếu chỉ một mình bạn lo thật không biết làm
sao nhớ cho hết. Cũng may là nhà hàng sẽ đảm trách luôn cả việc in ấn
thiệp mời, ban nhạc văn nghệ và cả hoạt náo viên. Thủ tục nghi lễ thì
không ai qua
được bác Sáu Đạt, và bác đã nhận lời mua quà cáp, lo về tiếp tân, xe cộ
và thủ tục, nghi lễ. Bác cũng sẽ liên lạc với Mục sư chủ lễ để dặn chỗ
nhà thờ
và sắp đặt ngừơi giựt chuông và người đàn. Anh Tư Thông có người bạn làm
chủ tiệm hình, nên anh nhận trách nhiệm mướn người lo chụp
hình, quay phim. Như thế việc bạn tổ chức cái đám cưới nay rút lại chỉ
còn soạn danh sách quan khách, các bài diễn văn, sắp chỗ ngồi và dặn chỗ
cho cặp
vợ chồng mới đi hưởng tuần trăng mật.

Sở dĩ bạn cảm thấy trách nhiệm tổ chức không nặng nề vì nhà hàng, bác
Sáu Đạt và anh Tư Thông tự lo gánh vác các khâu rắc rối. Cái hay ở đây

những người nầy tự lo quyết định mọi chi tiết của những gì cần phải làm
trong khâu của họ. Chỉ khi nào cần lắm, họ mới liên lạc để lấy ý kiến
của
bạn. Họ giống như những người thầu của bạn.
Chắc bạn đã lưu ý rằng cái thí dụ tổ chức đám cưới nầy cho thấy nói chung muốn triển khai dự án lớn nào ta cần phải nhờ những
người thầu giúp đở. Quả thật, đó là cách các quản trị viên những công trình đã làm từ xưa đến nay.

Bây giờ trở lại chuyện lập trình, phải chi ta có thể tổ chức cách triển
khai dự án phần mềm giống như tổ chức cái đám cưới nói trên thì tốt quá.
Thật ra, không phải các lý thuyết gia phần mềm
không nghĩ đến chuyện ấy trước đây, nhưng để thực hiện được việc ấy
người ta cần triển khai các phương tiện, dụng cụ thích hợp.
Chỉ trong vòng 15 năm trở lại đây, việc ấy mới trở nên cụ thể qua các
Operating Systems tinh vi, nhất là dùng Windows, và các ngôn ngữ
lập trình như Eiffel, SmallTalk, C++ .v.v..
Lập trình theo hướng đối tượng (Object Oriented Programming)



Nói một cách nôm na, lập trình theo hướng đối tượng là thiết kế các bộ phận phần mềm của chương trình, gọi là Objects sao cho mỗi
bộ phận có thể tự lo liệu công tác của nó giống như một người thầu ngoài đời vậy. Chắc có lẽ bạn sẽ hỏi thế thì các Sub
hay Function mà bạn đã từng viết để xử lý từng giai đoạn trong chương trình có thể đảm trách vai trò của một thầu không?
Người thầu chẳng những có thể làm được công tác (Subs và Functions) gì mà còn
chịu trách nhiệm luôn cả mọi thứ vật dụng cần thiết (data) cho việc ấy nữa.

một cách định nghĩa khác cho Object là một Object
gồm có data structure và các Subs/Functions làm việc trên các data ấy.
Thông thường, khi ta dùng Objects ít khi giám thị chúng, ngược lại
nếu khi có sự cố gì thì ta muốn chúng báo cáo cho ta biết.

Trong VB6, các Forms, Controls hay ActiveX là những Objects mà ta vẫn
dùng lâu nay. Lấy thí dụ như Listbox. Một Listbox tự
quản lý các items hiển thị bên trong nó. Ta biết listbox List1 đang có
bao nhiêu items bằng cách hỏi List1.ListCount. Ta biết item nào vừa
mới được selected bằng cách hỏi List1.ListIndex. Ta thêm một item vào
listbox bằng cách gọi method AddItem của List1, ..v.v..
Nói cho đúng ra, Object là một thực thể của một Class. Nếu Listbox là
một Class thì List1, List2 là các thực thể của Listbox. Cũng
giống như Bà Tư Cháo Lòng và Dì Sáu Bánh Tầm là các thực thể của Class
Đầu Bếp.
Ngay cả một form tên frmMyForm mà ta viết trong VB6 chẳng hạn, nó cũng là một Class. Thường thường ta dùng thẳng frmMyForm
như sau:
<blockquote><blockquote>
frmMyForm.Show
</blockquote></blockquote>
Trong trường hợp nầy thật ra frmMyForm tuy là một Class nhưng được dùng y như một Object. Chớ nếu muốn, ta có thể tạo
ra hai, ba Objects của Class frmMyForm cùng một lúc như trong thí dụ sau:
<blockquote><blockquote>
Dim firstForm As frmMyForm
Dim secondForm As frmMyForm
Set firstForm = New frmMyForm
Set secondForm = New frmMyForm
firstForm.Show
secondForm.Show
</blockquote></blockquote>
Trong thí dụ trên ta declare firstForm và secondForm là những Objects của Class frmMyForm. Sau đó ta làm nên (instantiate) các Objects firstForm và secondForm bằng statements Set... = New...
firstForm và secondForm còn được gọi là các instances của Class
frmMyForm. Class giống như cái khuôn, còn Objects giống như những cái
bánh
làm từ khuôn ấy. Chắc bạn đã để ý thấy trong VB6 từ dùng hai từ Class và
Object lẫn lộn nhau. Đều nầy cũng không quan trọng, miễn là bạn nắm
vững
ý nghĩa của chúng.

VB6 có yểm trợ Class mà ta có thể triển khai và instantiate các Objects của nó khi dùng. Một Class trong VB6 có chứa data riêng của nó, có những SubsFunctions mà ta có thể gọi. Ngoài ra Class còn có thể
Raise Events, tức là báo cho ta biết khi chuyện gì xãy ra bên
trong nó. Cũng giống như Event Click của CommandButton, khi User clicks
lên button thì nó Raise Event Click để cho ta xử lý trong Sub
myCommandButton_Click(), chẳng hạn. Classtrong VB6 không có hổ trợ
Visual components, tức là không có chứa
những controls như TextBox, Label .v.v.. Tuy nhiên, ta có thể lấy những
control có sẵn từ bên ngoài rồi đưa cho Object của Class dùng.


Bây giờ chúng ta hãy bắt đầu viết một Class. Bạn hãy mở một Project mới
loại Standard EXE Visual Basic. Sau đó dùng Menu Command chọn Add Class Module:
<blockquote></blockquote>
Khi Add Class Module dialog hiện ra chọn Class Module và click Open.
<blockquote></blockquote>
Bạn sẽ thấy mở ra một khung trắng và Project Explorer với Properties
Window. Trong Properties Window, hãy sửa Name property của Class thành
clsBox như dưới đây:
<blockquote></blockquote>
Kế đó đánh vào những dòng code dưới đây, hay download source code của chương trình ClassBox.zip, trong đó có biểu diển cách dùng Class clsBox.

Option Explicit
Private mX As Integer
Private mY As Integer
Private mWidth As Integer
Private mHeight As Integer

Public Property Let X(ByVal vValue As Integer)
mX = vValue
End Property

Public Property Get X() As Integer
X = mX
End Property

Public Property Let Y(ByVal vValue As Integer)
mY = vValue
End Property

Public Property Get Y() As Integer
Y = mY
End Property

Public Property Let Width(ByVal vValue As Integer)
mWidth = vValue
End Property

Public Property Get Width() As Integer
Width = mWidth
End Property

Public Property Let Height(ByVal vValue As Integer)
mHeight = vValue
End Property

Public Property Get Height() As Integer
Height = mHeight
End Property

Public Sub DrawBox(Canvas As Object)
Canvas.Line (mX, mY)-(mX + mWidth, mY + mHeight), , B
End Sub

Public Sub ClearBox(Canvas As Object)
Canvas.Line (mX, mY)-(mX + mWidth, mY + mHeight), Canvas.BackColor, B
End Sub
Class clsBox có 4 Properties: X, Y, Width và Height. Ta sẽ instantiate
một Box từ clsBox. Mỗi Box có tọa độ (X,Y) và kích thước chiều
rộng và chiều cao (width, height) của nó. Thật ra ta có thể dùng Public
statement để declare các biến X, Y, Width và Height. Nhưng ở
đây ta cố ý declare chúng là Private, dưới dạng mX, mY, mWidth và
mHeight. Khi ta muốn thay đổi các trị số của chúng, ta sẽ dùng cùng
một cách viết code như bình thường (thí dụ: myBox.X = 80 ). Nhưng khi
chương trình xử lý assignment statement ấy, nó sẽ
execute một loại method (giống như Sub) gọi là Property Let X (vValue).
Ta thấy ở đây vValue được assigned cho mX (i.e. mX = vValue ), cái
Private variable của X.
Như thế công việc nầy cũng chẳng khác gì sửa đổi một Public variable X.
Tuy nhiên, ở đây ta có thể viết thêm code trong Property Let X để nó
làm gì cũng được.
Bạn có nhớ trong khi thiết kế một Label, mỗi lần bạn dùng Property
Window để edit Font size, forcolor hay backcolor thì chẳng những các
properties ấy của Label
thay đổi, mà kết quả của sự thay đổi được có hiệu lực ngay lập tức,
nghĩa là Label được hiển thị trở lại với trị số mới của property. Đó là
vì trong method Property có cả code bảo Label redisplay.
Ngược lại, khi ta dùng property X của Object myBox, không phải ta chỉ đọc trị số thôi mà còn execute cả cái method Property Get X.
Nói tóm lại, Property cho ta cơ hội để execute một method mỗi khi User đọc hay viết trị số variable ấy.
Thí dụ như nếu ta muốn kiểm soát để chỉ chấp nhận trị số tọa độ X mới
khi nó không phải là số âm. Ta sẽ sửa Property Let X lại như sau:

Public Property Let X(ByVal vValue As Integer)
If (vValue >= 0) Then
mX = vValue
End If
End Property
Property có thể là Read Only hay Write Only. Nếu muốn một Property là Read Only thì ta không cung cấp Property Let.
Nếu muốn một Property là Write Only thì ta không cung cấp Property Get. Ngoài ra nếu làm việc với Object, thay vì Data type thông thường, thì ta phải dùng Property Set, thay vì Property Let.
Thí dụ ta cho clsBox một Property mới, gọi là Font dùng object của class
stdFont của VB6. Trong clsBox ta declare một Private variable mFont và
viết một Property Set Font như sau:

Private mFont As StdFont
Public Property Set Font(ByVal newFont As StdFont)
Set mFont = newFont
End Property
Ta sẽ dùng property Font của myBox (thuộc Class clsBox) như sau:

' Declare an object of Class StdFont of VB6
Dim myFont As StdFont
Set myFont = New StdFont
myFont.Name = "Arial"
myFont.Bold = True
Dim myBox As clsBox
Set myBox = New clsBox
Set myBox.Font = myFont ' Call the Property Set method
Class clsBox có hai Public Subs, DrawBoxClearBox. ClearBox cũng vẽ một box như DrawBox, nhưng nó dùng BackColor của màn ảnh (canvas), nên coi như xóa cái box có sẵn. Do đó,
nếu muốn, bạn có thể sửa Sub DrawBox lại một chút để nhận một Optional draw color như sau:

Public Sub DrawBox(Canvas As Object, Optional fColor As Long)
If IsMissing(fColor) Then
Canvas.Line (mX, mY)-(mX + mWidth, mY + mHeight), , B
Else
Canvas.Line (mX, mY)-(mX + mWidth, mY + mHeight), fColor, B
End If
End Sub
Trong thí dụ trên, Optional parameter fColor được tested bằng function IsMissing. Nếu fColor là BackColor của canvas thì ta sẽ có hiệu quả của ClearBox.
Trong form chính của chương trình dùng để test clsBox, mỗi khi ta refer
đến một object thuộc class clsBox, IDE Intellisense sẽ hiển thị
các Properties và Subs/Functions của clsBox như trong hình dưới đây:

<blockquote></blockquote>
Trong chương trình nầy, mỗi khi ta click nút Draw thì một Box được instantiate, cho tọa độ X,Y và kích thước Width, Height, rồi được
vẽ ra ngay trên form. Chữ Me trong code nói đến chính cái form frmClass.
<blockquote></blockquote>
Để cho chương trình thú vị hơn, khi user clicks nút Animate, ta sẽ cho một box màu đỏ chạy từ trái qua phải.
Khi user clicks nút Two Boxes ta sẽ vẽ hai boxes, hộp trong màu
xanh, hộp ngoài màu đỏ, và cho chúng chạy từ trái sang phải. Ở đây ta
biểu diễn cho thấy mình muốn instantiate bao nhiêu
boxes từ clsBox cũng được, và dĩ nhiên mỗi box có một bộ properties với
giá trị riêng của nó.

<blockquote></blockquote>
Ta có thể lập trình để cho Object báo cáo program chủ của nó khi có một biến cố (Event) xãy ra bên trong Class.
Ta thử declare một Event tên Draw trong clsBox, và viết code để mỗi khi Sub DrawBox executes thì Class sẽ Raise một event Draw.

Public Event Draw(X As Integer, Y As Integer)
Public Sub DrawBox(Canvas As Object, Optional fColor As Long)
If IsMissing(fColor) Then
Canvas.Line (mX, mY)-(mX + mWidth, mY + mHeight), , B
Else
Canvas.Line (mX, mY)-(mX + mWidth, mY + mHeight), fColor, B
End If
RaiseEvent Draw(mX, mY)
End Sub
<blockquote></blockquote>
Bây giờ, trong frmClass thay vì chỉ declare Dim myBox as clsBox, ta sẽ declare Private WithEvents myBox as clsBox. Ngay sau đó, chữ myBox
sẽ
hiện ra trong danh sách các Object có hổ trợ Event của frmClass. Kế đó
ta sẽ viết code để handle Event Draw của myBox, tức là ta cung cấp code
cho Private Sub myBox_Draw (X as Integer, Y as Integer). Ở đây ta chỉ hiển thị một sứ điệp báo cáo một hộp vừa được vẽ ở đâu.

<blockquote></blockquote>
Khi chạy program, mỗi lần một clsBox object executes Sub DrawBox ta sẽ thấy frmClass display một message giống như dưới đây.

<blockquote></blockquote>
Nhớ rằng, ta declare một Object với WithEvents khi ta muốn handle các
Events của nó. Trong thí dụ trên frmClass là chủ của myBox và nó handles
Event Draw của myBox.
Tương tự như vậy, ngay cả ở bên trong một Class, nếu Class ấy được giao
cho một Object có thể Raise Events (thí dụ như TextBox, ListBox, Timer
.v.v..), bạn cũng có thể
declare Object ấy WithEvents để nó có thể handle Events của Object.
Trong thí dụ dưới đây ta viết codes nầy trong một Class đã được giao cho
một Textbox khi form chính gọi Sub InitObject để đưa cho Object một
TextBox:

Private WithEvents mTextBox As TextBox

Public Sub InitObject(givenTextBox As TextBox)
Set mTextBox = givenTextBox
End Sub

Private Sub mTextBox_KeyPress(KeyAscii As Integer)
' Place your code here to handle this event within the Class Object
End Sub
Để học thêm về cách dùng Class, mời bạn đọc qua các Classes trong phần Source Code VB6 của trang chủ Học Microsoft Visual Basic 6.0.
</blockquote>
Chữ Ký Cá Nhân

Về Đầu Trang Go down
Xem lý lịch thành viên
 

Chương Tám - Tự tạo Object (Học visual basic 6.0)

Xem chủ đề cũ hơn Xem chủ đề mới hơn Về Đầu Trang 
Trang 1 trong tổng số 1 trang

Permissions in this forum:Bạn không có quyền trả lời bài viết
Vn-Screen Forum :: Công Nghệ Thông Tin :: Khu Lập Trình :: Visual Basic-
VN-SCREEN.DARKBB.COM
Design by N.H.M - Developed by Vn-Screen Member
Free forum | © phpBB | Free forum support | Liên hệ | Report an abuse | Sosblogs.com